BBC Dataset Sample Queries

These queries demonstrate some of the types of queries that can be done over the BBC dataset

• EastEnders episodes

  List all episodes of EastEnders from the programmes data.

  PREFIX po: <http://purl.org/ontology/po/>
  PREFIX dc: <http://purl.org/dc/elements/1.1/>
                
  select distinct ?title ?short_syn 
  where { 
    <http://www.bbc.co.uk/programmes/b006m86d#programme> po:episode ?e .  
    ?e a po:Episode .  
    ?e po:short_synopsis ?short_syn .
    ?e dc:title ?title
  }
                

  Run in SPARQL endpoint Open in iSPARQL

• Led Zeppelin Record Reviews

  Get reviews of Led Zeppelin records, with reviewer name.

  PREFIX mo:   <http://purl.org/ontology/mo/>
  PREFIX foaf: <http://xmlns.com/foaf/0.1/>
  PREFIX dc:   <http://purl.org/dc/elements/1.1/>
  PREFIX rev:  <http://purl.org/stuff/rev#>
  
  select distinct ?rtitle ?rtext ?rvname
  where {
    ?rec foaf:maker <http://www.bbc.co.uk/music/artists/678d88b2-87b0-403b-b63d-5da7465aecc3#artist> .
    ?rec a mo:Record .
    ?rec dc:title ?rtitle .
    ?rev a rev:Review .
    ?rev foaf:primaryTopic ?rec .
    ?rev rev:text ?rtext .
    ?rev rev:reviewer ?rviewer .
    ?rviewer foaf:name ?rvname
  }
  
                

  Run in SPARQL endpoint Open in iSPARQL

• John Paul Jones' Records

  List records involving John Paul Jones

  PREFIX mo:   <http://purl.org/ontology/mo/>
  PREFIX foaf: <http://xmlns.com/foaf/0.1/>
  PREFIX dc:   <http://purl.org/dc/elements/1.1/>
  PREFIX rev:  <http://purl.org/stuff/rev#>
  PREFIX po:   <http://purl.org/ontology/po/>
  
  select distinct ?r_name, ?rev
  where {  
          {    
            <http://www.bbc.co.uk/music/artists/4490113a-3880-4f5b-a39b-105bfceaed04#artist> foaf:made ?r1 .
            ?r1 a mo:Record .
            ?r1 dc:title ?r_name .
            ?r1 rev:hasReview ?rev
          } UNION {
            <http://www.bbc.co.uk/music/artists/4490113a-3880-4f5b-a39b-105bfceaed04#artist> mo:member_of ?b1 .
            ?b1 foaf:made ?r1 .
            ?r1 a mo:Record .
            ?r1 dc:title ?r_name .
            ?r1 rev:hasReview ?rev
          }
        }  
                

  Run in SPARQL endpoint Open in iSPARQL